EjectorPump_CL
EjectorPump_CL provides a model of an ejector pump. This model follows the basic premise laid out by Eames et al. (1995) and others. The primary flow is modeled as passing through a nozzle with exit diameter D_p and efficiency eta_n_p. The exit pressure of the primary (and secondary) nozzle is P_n. The ratio of the secondary flow rate to the primary flow rate is the entrainment ratio (Rm). The secondary flow passes through an outer, annular nozzle that shares an exit pressure with the primary nozzle and has an efficiency (eta_n_s). The two flows then mix in a constant area duct. The momentum conservation in this duct is characterized by efficiency eta_m. If the mixing process results in supersonic flow then then the flow undergoes a shock to subsonic velocity before passing through a diffuser with efficiency eta_d and leaving at the exit pressure P_out.
CALL EjectorPump_CL(D_p, F$, P_p, T_p, P_s, T_s, eta_n_p, eta_n_s, eta_m, eta_d, P_n, Rm: m_dot_p, m_dot_s, P_out, h_out, D_s)
Inputs:
D_p Diameter of primary flow nozzle exit (m or ft)
F$ Name of an ideal gas or real fluid in the EES database
P_p: primary fluid inlet pressure (bar, atm, Pa, kPa, MPa)
T_p: primary fluid inlet temperature (C, K, F, R)
P_s: secondary fluid inlet pressure (bar, atm, Pa, kPa, MPa)
T_s: secondary fluid inlet temperature (C, K, F, R)
eta_n_p: primary nozzle efficiency (-)
eta_n_s: secondary nozzle efficiency(-)
eta_m: mixing zone efficiency (-)
eta_d: diffuser efficiency (-)
P_n: nozzle exit pressure (bar, atm, Pa, kPa, MPa)
Outputs:
m_dot_p: primary fluid mass flow rate (kg/s or lbm/s)
m_dot_s: secondary fluid mass flow rate (kg/s or lbm/s)
P_out: ejector pump exit pressure (bar, atm, Pa, kPa, MPa)
h_out: ejector pump exit specific enthalpy (J/kg, kJ/kg, or Btu/lbm)
D_s: secondary nozzle exit diameter (m or ft) - note that this is calculated from A_exit = pi/4*(D_s^2 - D_p^2)
Example 1 (with real fluid):
$Load Component Library
$UnitSystem SI Mass J K Pa
$VarInfo P_n P_out Units = 'Pa'
$VarInfo m_dot_p m_dot_s Units = 'kg/s'
$VarInfo D_s Units = 'm'
$VarInfo h_out Units = 'J/kg'
"Geometry"
D_p = 1 [mm]*Convert(mm,m)
"Conditions"
F$ = 'R134a'
P_p = 4 [bar]*Convert(bar,Pa)
T_p = 350 [K]
P_s = 0.5 [bar]*Convert(bar,Pa)
T_s = 290 [K]
"Performance parameters"
eta_n_p = 0.92
eta_n_s = 0.90
eta_m = 0.90
eta_d = 0.75
"nozzle exit pressure"
P_n = P_s*0.8
"entrainment ratio"
Rm = 0.35
CALL EjectorPump_CL(D_p, F$, P_p, T_p, P_s, T_s, eta_n_p, eta_n_s, eta_m, eta_d, P_n, Rm: m_dot_p, m_dot_s, P_out, h_out, D_s)
{Solution:
D_s=0.001476 [m]
m_dot_p=0.0004447 [kg/s]
m_dot_s=0.0001556 [kg/s]
h_out = 306422 [J/kg-K]
P_out=95621 [Pa]
}
Example 2 (with ideal gas):
$Load Component Library
$UnitSystem SI Mass kJ C kPa
$VarInfo P_n P_out Units = 'kPa'
$VarInfo m_dot_p m_dot_s Units = 'kg/s'
$VarInfo D_s Units = 'm'
$VarInfo h_out Units = 'kJ/kg'
"Geometry"
D_p = 1 [mm]*Convert(mm,m)
"Conditions"
F$ = 'Air'
P_p = 4 [bar]*Convert(bar,kPa)
T_p = 200 [C]
P_s = 0.8 [bar]*Convert(bar,kPa)
T_s = 29 [C]
"Performance parameters"
eta_n_p = 0.92
eta_n_s = 0.90
eta_m = 0.90
eta_d = 0.75
"nozzle exit pressure"
P_n = P_s*0.8
"entrainment ratio"
Rm = 0.35
CALL EjectorPump_CL(D_p, F$, P_p, T_p, P_s, T_s, eta_n_p, eta_n_s, eta_m, eta_d, P_n, Rm: m_dot_p, m_dot_s, P_out, h_out, D_s)
{Solution:
D_s=0.001448 [m]
m_dot_p=0.000353 [kg/s]
m_dot_s=0.0001236 [kg/s]
P_out=138.1 [kPa]
h_out = 430.9 [kJ/kg]
}